Sports Illustrated for Kids - Awesome Athletes!/Sports Illustrated for Kids - Awesome Athletes!.iso/hf.dir/00068_Search MS.ls

Text File | 1996-04-19 | 5.0 KB | 166 lines

global gHFoldTag, gHFSave33, gHFSave34, gHFSave35, gHFSave36, gHFCatLastLine, gHFsList, gHFsMax, gHFoldSList, gHFoldSMax, gHFoldSRes, gHFResultLastLine, gHFposition

on doSearchDialog
  set gHFoldTag to -1
  set gHFResultLastLine to 0
  set gHFoldSList to gHFsList
  set gHFoldSMax to gHFsMax
  set gHFoldSRes to the text of cast "Result List"
  set gHFCatLastLine to 1
  set gHFSave33 to the visible of sprite 33
  set gHFSave34 to the visible of sprite 34
  set gHFSave35 to the visible of sprite 35
  set gHFSave36 to the visible of sprite 36
  set the visible of sprite 33 to 1
  repeat with vI = 34 to 36
    set the visible of sprite vI to 1
  end repeat
  set the visible of sprite 44 to 0
  set the visible of sprite 45 to 0
  set the text of cast "Choise List" to EMPTY
  set the textFont of field "Cat List" to "Arial"
  set the textSize of field "Cat List" to 10
  if gHFsMax = 0 then
    set the text of cast "Result List" to "*No Matches Found*"
    set the textFont of field "Result List" to "Arial"
    set the textSize of field "Result List" to 10
    set the visible of sprite 28 to 0
  end if
  set the text of cast "Cat List" to EMPTY
  set the textFont of field "Cat List" to "Arial"
  set the textSize of field "Cat List" to 10
  set the text of cast "SDKeyword Field" to EMPTY
  set the textFont of field "SDKeyword Field" to "Arial"
  set the textSize of field "SDKeyword Field" to 12
  puppetSound("pheeu.aif")
  go("Search")
  puppetSprite(24, 1)
  setCategory(#sports)
end

on endSearchDialog
  puppetSprite(23, 0)
  puppetSprite(24, 0)
  set gHFoldSList to []
  set gHFoldSMax to 0
  set gHFoldSRes to EMPTY
  set the visible of sprite 28 to 1
  set the visible of sprite 33 to gHFSave33
  set the visible of sprite 34 to gHFSave34
  set the visible of sprite 35 to gHFSave35
  set the visible of sprite 36 to gHFSave36
  set the visible of sprite 37 to 1
  set the visible of sprite 44 to 1
  set the visible of sprite 45 to 1
  go(1)
end

on setCategory aCat
  if aCat = #sports then
    set the text of cast "Cat List" to the text of cast "SDSports List"
    set vTagSprite to 33
    set vCat to the number of cast "SDSports-down"
    set vFrame to "Search"
  else
    if aCat = #event then
      set the text of cast "Cat List" to the text of cast "SDEvent List"
      set vTagSprite to 34
      set vCat to the number of cast "SDEvents-down"
      set vFrame to "Search-2"
    else
      if aCat = #awards then
        set the text of cast "Cat List" to the text of cast "SDAwards List"
        set vTagSprite to 35
        set vCat to the number of cast "SDAwards-down"
        set vFrame to "Search-3"
      else
        if aCat = #other then
          set the text of cast "Cat List" to the text of cast "SDOther List"
          set vTagSprite to 36
          set vCat to the number of cast "SDOther-down"
          set vFrame to "Search-4"
        end if
      end if
    end if
  end if
  go(vFrame)
  set the castNum of sprite 24 to vCat
  set the textFont of field "Cat List" to "Arial"
  set the textSize of field "Cat List" to 10
end

on addDelCategory aCat
  set aCat to aCat & RETURN
  set vTmp to the text of cast "Choise List"
  set vPos to offset(aCat, vTmp)
  if vPos = 0 then
    set vTmp to vTmp & aCat
  else
    delete char vPos to vPos + the number of chars in aCat - 1 of vTmp
  end if
  set the text of cast "Choise List" to vTmp
  set the textFont of field "Choise List" to "Arial"
  set the textSize of field "Choise List" to 10
  set the foreColor of cast "Choise List" to 255
end

on doSearch
  SetCursor(#wait)
  set vText to the text of cast "Choise List"
  set vKeywords to []
  set vlines to the number of lines in vText - 1
  repeat with vI = 1 to vlines
    add(vKeywords, line vI of vText)
  end repeat
  set vRet to AthleteSearch(EMPTY, vKeywords)
  set vResult to EMPTY
  set vMax to count(vRet)
  set gHFsMax to vMax
  set gHFsList to []
  if gHFsMax = 0 then
    set vResult to "*No Matches Found*"
    set the visible of sprite 28 to 0
  else
    set the visible of sprite 28 to 1
    repeat with vI = 1 to vMax
      set vInfo to GetAthInfo(getAt(vRet, vI))
      add(gHFsList, vInfo)
      set vResult to vResult & item 5 of vInfo & RETURN
    end repeat
  end if
  set the text of cast "Result List" to " "
  set the textFont of field "Result List" to "Arial"
  set the textSize of field "Result List" to 12
  set the foreColor of cast "Result List" to 255
  put vResult before field "Result List"
  SetCursor(#normal)
end

on resetSearch
  set the text of cast "Choise List" to EMPTY
  set the text of cast "SDKeyword Field" to EMPTY
  set gHFsMax to 0
  set gHFsList to []
  set the text of cast "Result List" to "*No Matches Found*"
  set the textFont of field "Result List" to "Arial"
  set the textSize of field "Result List" to 12
  set the foreColor of cast "Result List" to 255
end

on searchGoto aPos
  if voidp(aPos) or voidp(gHFsMax) then
    beep()
    exit
  end if
  if (aPos < 1) or (aPos > gHFsMax) then
    beep()
    exit
  end if
  SetCursor(#wait)
  endSearchDialog()
  setAthleteMode(0, 1)
  set gHFposition to aPos
  paintscreen()
  SetCursor(#normal)
end